Welcome to RunSubmit.com

Question

3

How can I determine the name and path of the program I am currently running? (In Windows, sas 9.1.3 - but techniques for other versions / environments would also be good to know..)

edited Nov 13 at 15:09

jay.l.stevens♦
793●8

asked Nov 6 at 11:10

NextLevel-IS
259●5

cmjohns · Accepted Answer · 2009-11-06 15:43:05Z UTC

You can use the Environment variables SAS_EXECFILEPATH and SAS_EXECFILENAME.

like so...

%macro xfilepath;
  %sysget(SAS_EXECFILEPATH)
%mend xfilepath;
%put %xfilepath;

%macro xfile;
  %sysget(SAS_EXECFILENAME)
%mend xfile;
%put %xfile;

On Unix/Linux systems (but only in batch mode - not dms) you could probably use the dictionary.extfiles table (or sashelp.vextfl) since SAS_EXECFILEPATH and SAS_EXECFILENAME are Windows only environment variables:

proc sql noprint;
select 
  scan(xpath,-1,'/') into :xfile
  from dictionary.extfiles
  where upcase(xpath) like '%.SAS';
select 
  xpath into :xfilepath
  from dictionary.extfiles
  where upcase(xpath) like '%.SAS';
quit;
%put &xfile.;
%put &xfilepath.;

WilliamDobson · Answer 2 · 2009-11-06 15:33:35Z UTC

3

The following paper expands on the above answer by resolving windows filepaths into UNC paths, which should make code reliant on access to the location, rather than potentially transient drive mappings: The Path, The Whole Path, And Nothing But the Path, So Help Me Windows

answered Nov 6 at 15:33

WilliamDobson
237●6

two excellent answers - so I chose the one that arrived first! – NextLevel-IS Nov 7 at 12:00

jay.l.stevens · Answer 3 · 2010-07-04 16:51:53Z UTC

To get the last opened filename:

data _null_;
set sashelp.vextfl(where=(upcase(xpath) like '%.SAS'));
call symput('program', scan(xpath,-1,'\'));
run;

%put &program;

**result: filename.sas**

To get filepath, use the following code;

data _null_;
set sashelp.vextfl
(where=(upcase(xpath) like '%.SAS'));
call symput('program', xpath)); 
run;

%put &program;

**Result:**
H:\Company\Client\Study\ABC304\Programs\filename.sas

Sarath Annapareddy StudySAS Blog

Tom Robinson · Answer 4 · 2010-07-12 05:32:31Z UTC

2

In batch mode you can use:

%put %sysfunc(getoption(sysin));

answered Jul 12 at 5:32

Tom Robinson
31●1

This is much more elegant, but won't work when in interactive debugging mode; unless, I guess you could specify the -sysin at session startup and then it would still work properly. – jay.l.stevens♦ Jul 12 at 12:16

PeterC · Answer 5 · 2010-01-13 10:09:21Z UTC

1

beware the Environment variables SAS_EXECFILEPATH and SAS_EXECFILENAME
These are filled through the "file-open" dialog of enhanced editor (hence windows-only). Since there can be more than one such editor window open, which do you think the (single) environment variable SAS_EXECFILEPATH should show?

answered Jan 13 at 10:09

PeterC
29●2

I'm pretty sure this is correct and shouldn't have been downvoted since when running in batch (even on Windows) SAS_EXECFILEPATH and SAS_EXECFILENAME don't appear to be populated. – jay.l.stevens♦ Apr 9 at 4:49

Finding out the name and path of the program being run

Remember to vote up questions/answers you find interesting or helpful (requires 15 reputation points)

5 Answers